Wie schalte ich das aktive Fenster unter MacOS auf Knopfdruck in den Vollbildmodus? Oder genauer: Wie sage ich dem aktiven...

Wie schalte ich das aktive Fenster unter MacOS auf Knopfdruck in den Vollbildmodus? Oder genauer: Wie sage ich dem aktiven Fenster, daß es die maximal mögliche Bildschirmfläche zur Anzeige nutzen soll? Das ist es nämlich genau das, was das kleine grüne Knöpfchen aus der ampelfarbenen Buttonleiste jedes Mac-Fensters tut. Allerdings nur, wenn es mit der Maus geklickt wird. Von Haus aus bietet MacOS keinen Tastatur-Shortcut, um diese Funktion aufzurufen.

Mit ein wenig Applescript und einem Tool, daß Hotkey-gesteuert Apple-Skripte starten oder ausführen kann, lässt sich jedoch Abhilfe schaffen. Wir zeigen einen Lösungsweg mit dem sehr mächtigen Productivity Tool Butler von Peter Maurer. Das Tool ist kostenlos und bietet unzählige Möglichkeiten auf die diese Guided Tour neugierig machten könnte.

So geht’s: In Customize-Dialog von Butler ein neues Smart Item “AppleScript” im Hidden-Bereich anlegen. Gewünschten Hotkey im Triggers-Tab wählen. Abschließend den folgenden Kode per Cut’n’Paste in das Source Code-Tab einfügen.

 
  1. -- A script to automatically zoom the frontmost window. 
  2. -- © 2006 by Daniel Jalkut, Inspired by:
  3. -- http://www.macosxhints.com/article.php?story=20051227001809626&lsrc=osxh
  4.  
  5. tell application "System Events"
  6.   set frontAppName to name of first application process whose frontmost is true
  7. end tell
  8.  
  9. set tryZoomedAttribute to true
  10. set tryMenuScripting to false
  11. set tryButtonScripting to false
  12. set allMethodsFailed to false
  13.  
  14. -- Special cases. For Applications whose behavior we know responds to one or the other
  15. -- method, force that method here.
  16. if (frontAppName is equal to "iTunes") then
  17.   set tryZoomedAttribute to false
  18.   set tryMenuScripting to true
  19. end if
  20.  
  21. if (tryZoomedAttribute is equal to true) then
  22.   tell application frontAppName
  23.     try
  24.       set zoomed of window 1 to not (zoomed of window 1)
  25.     on error
  26.       set tryMenuScripting to true
  27.     end try
  28.   end tell
  29. end if
  30.  
  31. -- Make sure the user has UI scripting enabled before we go on...
  32. if ((tryMenuScripting is equal to true) or (tryButtonScripting is equal to true)) then
  33.   tell application "System Events"
  34.     if UI elements enabled is false then
  35.       tell application "System Preferences"
  36.         activate
  37.         set current pane to pane "com.apple.preference.universalaccess"
  38.         display dialog "UI element scripting is not enabled. Check 'Enable access for assistive devices'"
  39.       end tell
  40.     end if
  41.   end tell
  42. end if
  43.  
  44. if (tryMenuScripting is equal to true) then
  45.   tell application "System Events"
  46.     tell process frontAppName
  47.       try
  48.         click menu item "Zoom" of menu of menu bar item "Window" of menu bar 1
  49.       on error
  50.         set tryButtonScripting to true
  51.       end try
  52.     end tell
  53.   end tell
  54. end if
  55.  
  56. if (tryButtonScripting is equal to true) then
  57.   -- UI Scripting method:
  58.   tell application "System Events"
  59.     try
  60.       tell process frontAppName
  61.         click button 2 of window 1
  62.       end tell
  63.     on error
  64.       set allMethodsFailed to true
  65.     end try
  66.   end tell
  67. end if
  68.  
  69. if (allMethodsFailed is equal to true) then
  70.   display dialog "I'm sorry, I couldn't figure out how to zoom this window."
  71. end if

Leave a Reply

Your email address will not be published. Required fields are marked *